Stop() - The Stop Command

Task14()
{
Name="Leaving Task"
Start(A=200,P=4) //Starts on P4 for Area 200
Stop(A=200,P=1)  //End if the welcome trigger is heard
Preset=4
Fade=2
Delay=.2       //Set a default delay of 200ms
Preset(A=4)    //Turn off the living room lights
Delay()
Preset(A=9)    //Turn off the dining room lights
Delay()
Preset(A=5)    //Turn off the kitchen lights
Delay()
Preset(A=11)   //Turn off the bedroom lights
Null
}

Task1()

{
Start(A=100,P=1)    //Start on and Area 100 P1 message
Stop(A=100,P=4)     //Stop on an Area 100 P4 message
Area=11             //Set Default Area to 11 (RGB Lights)
Delay=1.5           //Set Default Delay time to 1.5s
Fade=1              //Set Default Fade time to 1s
Loop:
    Preset(P=5)     //Recall Preset 5 (Red)
    Delay()         //Delay between colors
    Preset(P=6)     //Recall Preset 6 (Yellow)
    Delay()
    Preset(P=7)     //Recall Preset 7 (Green)
    Delay()
    Preset(P=8)     //Recall Preset 8 (Teal)
    Delay()
    Preset(P=9)     //Recall Preset 9 (Blue)
    Delay()
    Preset(P=10)    //Recall Preset 10 (Magenta)
    Delay()
    BRA Loop        //Loop back to the top and repeat.
}

Task14()
{
Name="Do Not Disturb Tracker"
Stop(0x1C,3,0x00,0x4C,0x00,x,0xFF)      //Stops on DND for Area 3
...
}

Task1()
{
    Name="Bogus Trigger task"
    Start(0x1c,x,x,x,x,x,x) //Watches all incoming 1C logical messages. Starts on any logical message.
    Stop(0x1c,250,x,x,x,x,x) //Watches all incoming 1C logical messages. Stops the task if the area is 250.
    copy @0,~0,7    //Copy the msg to ~0-~6.  ~1 is area, ~3 is preset
    LDA ~1          //Load the area
    CMP #2          //Is it area 2?
    BRZ Area2
    CMP #3          //Is it area 3?
    BRZ Area3
    Null
    Area2:
        LDA ~3          //Get Preset byte (The Op code)
        CMP #0x00       //Check if it the incoming Preset is Preset 1
        BRZ A2P1        //If it matches branch down to P1: Label.  If not continue.
        CMP #0x03       //Check if it the incoming Preset is preset 4
        BRZ A2P4
        Null            //Stop.
        A2P1:
            //Do something
            Null
        A2P4:
            //Do something
            Null
...
}

Task14()
{
Name="Area 65000"
Stop(0xAC,0x01,x,x,0xFDE8,0xFF,0x00,x,x) //Stop the task on a D2 A65000 Preset message with join of 0xFF
...
}

Task14()
{
Name="Welcome Task"
Start("Hello")      //Starts on the string "Hello"
Stop("GoodBye")     //Stops on the string "GoodBye"
...
}

Task14()
{
Name="Temperature capture"
Start("Temp A%d %d.%d",~7,~6,~5)    //The command matches any incoming packet that starts with "Temp", a space, the letter "A" and a number, a space, and a number with a decimal point, and another number. The numbers are stored in ~7, ~6 and ~5 respectively. ex "Temp A5 24.5"
Stop("HVAC A%d Mode%d",~8,~9)     //The task will stop on any string that starts with "HVAC", a space, the letter "A" and a number, a space, "Mode" and a number. The numbers are stored in ~8, and ~9 respectively. ex "HVAC A1 Mode3"
...
}